Installation#

MGPP was published on Gradle Plugin Portal.

Please make sure to always upgrade MGPP to the latest version:

Mindustry	MGPP Version
≤ 135.2	v 1.1.1
≥ 136	v 1.3.0

Gradle setup#

Using the plugins DSL:

GroovyKotlin

plugins {
    id "io.github.liplum.mgpp" version "<version>"
}

plugins {
    id("io.github.liplum.mgpp") version "<version>"
}

Using legacy plugin application:

GroovyKotlin

buildscript {
    repositories {
        maven { url "https://plugins.gradle.org/m2/" }
    }
    dependencies {
        classpath "io.github.liplum.mgpp:MindustryGradlePluginPlumy:<version>"
    }
}

apply plugin: "io.github.liplum.mgpp"

buildscript {
    repositories {
        maven { url = uri("https://plugins.gradle.org/m2/") }
    }
    dependencies {
        classpath("io.github.liplum.mgpp:MindustryGradlePluginPlumy:<version>")
    }
}

apply(plugin = "io.github.liplum.mgpp")

Configuration#

For ease of understanding, simplified examples are used here. Of course, it can still work for you.

GroovyKotlin

mindustry {
       dependency {
        mindustry version: 'v136'
        arc version: 'v136'
    }
    client {
        official version: 'v136' 
    }
    server {
        official version: 'v136'
    }
}
mindustryAssets {
    rootAt "$projectDir/assets"
}

import io.github.liplum.mindustry.*
mindustry {
    dependency {
        mindustry on "v136"
        arc on "v136"
    }
    client {
        mindustry official "v136"
    }
    server {
        mindustry official "v136"
    }
}
mindustryAssets {
    root at "$projectDir/assets"
}

Dependency setup#

You can import the repositories where Mindustry was published by mindustryRepo().

You can use importMindustry() to import the Mindustry dependencies you have configured above.

GroovyKotlin

repositories {
    mavenCentral()
    mindustryRepo()
}
dependencies {
    importMindustry()
}

import io.github.liplum.mindustry.*
repositories {
    mavenCentral()
    mindustryRepo()
}
dependencies {
    importMindustry()
}